# elem.ludic - an element made from its template: what kind of node its tag is, its id, classes
# and attributes (kept for selectors, applied after every rule), its text, and its children
const EL_BOXES: string = " col div progress meter section header footer nav main article aside ul ol li form box "
const EL_TEXTS: string = " text span p label h1 h2 h3 h4 h5 h6 strong em small b i a option "
function bd_elem(ui_st: mut UiState, k: UiTpl, e: UiEnv, key: string) -> UiNode {
  ui_st.ui_at = k.where
  let n = nd_take(ui_st)
  n.key = key
  n.tag = k.tag
  n.env = e
  n.sheet = k.sheet
  n.style = k.style
  el_kind(ui_st, n, k.tag)
  for i in 0 .. len(k.keys) { el_keep(ui_st, n, k.keys[i], ui_eval(ui_st, k.vals[i], e)) }
  n.hovered = fr_was_hovered(ui_st, key)
  n.on_names = k.on_keys
  n.on_acts = k.on_acts
  for i in 0 .. len(k.on_keys) {
    if k.on_keys[i] == "press" { n.act = k.on_acts[i] }
  }
  lc_note(ui_st, key, k.on_keys, k.on_acts, e)
  let was_no = ui_st.tr_no
  let say = ui_attr_text(n, "translate")
  if say == "no" { ui_st.tr_no = true } else if say == "yes" { ui_st.tr_no = false }
  bd_kids(ui_st, k.kids, e, key, n.children)
  if k.text != null { el_text(ui_st, n, ui_tr(ui_st, ui_eval_text(ui_st, k.text, e))) }
  el_inline(ui_st, n)
  if k.tag == "input" or k.tag == "select" or k.tag == "progress" or k.tag == "meter" { ct_build(ui_st, n) }
  ui_st.tr_no = was_no
  return n
}
function el_kind(ui_st: mut UiState, n: UiNode, tag: string) -> void {
  let nv = nt_find(ui_st, tag)
  if nv != null {
    n.kind = UI_NATIVE
    n.native = nv
  } else if lk_in(EL_TEXTS, tag) { n.kind = UI_TEXT } else if tag == "row" { n.dir = UI_ROW } else if tag == "button" {
    n.dir = UI_ROW
    n.focusable = true
  } else if tag == "input" or tag == "select" { n.focusable = true } else if tag == "spacer" { n.kind = UI_SPACER } else if tag == "scroll" { n.kind = UI_SCROLL } else if tag == "img" { n.kind = UI_IMAGE } else if tag == "hr" { n.kind = UI_RULE } else if not lk_in(EL_BOXES, tag) { el_unknown(ui_st, tag) }
}
# a box with words in it holds them as a text of its own, as <div>words</div> does
function el_text(ui_st: mut UiState, n: UiNode, s: string) -> void {
  if n.kind != UI_BOX and n.kind != UI_SCROLL {
    n.text = s
    return
  }
  let t = nd_take(ui_st)
  t.kind = UI_TEXT
  t.text = s
  t.env = n.env
  ui_kept(n.children, t)
}
# id, class, hidden, disabled and src say what the element is; the rest are applied after the rules
# an attribute's text is worked out only where it is read as text (the rest keep their Value; a selector
# that asks for one reads it then) - a float's text written per element per frame was a leak
function el_keep(ui_st: mut UiState, n: UiNode, key: string, v: Val) -> void {
  if key == "id" { n.id = vl_text_u(ui_st, v) } else if key == "class" {
    let parts = mm_split(ui_st, vl_text_u(ui_st, v), 32)
    for i in 0 .. len(parts) {
      if len(parts[i]) > 0 { ui_kept(n.classes, parts[i]) }
    }
  } else if key == "popover" {
    n.popover = true
    n.pos = 2
    ui_kept(n.akeys, key)
    ui_kept(n.avals, "")
    ui_kept(n.vals, v)
  } else if key == "tabindex" { n.focusable = vl_text_u(ui_st, v) != "-1" } else if key == "hidden" { n.hidden = el_flag(v) } else if key == "disabled" { n.enabled = not el_flag(v) } else if key == "src" { n.src = vl_text_u(ui_st, v) } else {
    if key == "enabled" { n.enabled = el_flag(v) }
    ui_kept(n.akeys, key)
    ui_kept(n.avals, "")
    ui_kept(n.vals, v)
  }
}

@alloc_ok("only when a template is wrong: a broken screen, never a working one")
function el_unknown(ui_st: mut UiState, tag: string) -> void { ui_err(ui_st, `<{tag}>: there is no such element`) }