# emit_machine.ludic — `machine <state> { state Name = v { .. } }` dispatches on
# an int state store; `become Name` writes the target state's value back. The
# store is either a named program-scope `var` (loaded/stored directly) or, for
# older code, a register index (reg()/set_reg()).

# If `a` names a program-scope `var`, return it; else null (a register index).
function machine_var(a: Node) -> Node {
  if a.kind == E_ID {
    let g = find_global(a.s)
    if (g != null) { if g.kind == N_VAR { return g } }
  }
  return null
}
# 0.S: a machine over a state's field (`machine hero.mode`) or a local: its address, else null
var g_mach_ty: pointer = null
function machine_addr(a: Node) -> pointer {
  if a.kind == E_MEMBER {
    let p = emit_member_addr(a)
    g_mach_ty = g_addr_ty
    return p
  }
  if a.kind == E_ID {
    let li = loc_find(a.s)
    if li >= 0 {
      g_mach_ty = loc_ty[li]
      return loc_reg[li]
    }
    let gv = machine_var(a)
    if gv != null {
      g_mach_ty = gv.ty
      return `@g_{a.s}`
    }
  }
  return null
}

# the value a state dispatches on: its explicit `= expr`; else, when the machine's
# store is a `var` declared with an enum type, the variant named like the state
# (`var mode: HeroState` + `state Rolling` -> HeroState.Rolling); else its ordinal.
function machine_state_value(m: Node, state: Node) -> pointer {
  if (state.b != null) { return emit_expr(state.b).code }
  g_mach_ty = null
  let addr = machine_addr(m.a)
  let ty = g_mach_ty
  if addr != null and ty != null {
    let ord = enum_ordinal(ty, state.s)
    if ord >= 0 { return itoa(ord) }
    if (find_enum(ty) != null) { perr(`machine state {state.s} is not a variant of enum {ty}`) }
  }
  return itoa(state.ival)
}

function emit_machine(st: Node) -> void {
  let addr = machine_addr(st.a)
  var s: pointer = ""
  if (addr != null) { s = emit_bind(`load i32, ptr {addr}`) }
  else {
    let regv = emit_expr(st.a)
    s = emit_bind(`call i32 {fn_sym("rt_reg")}(i32 {regv.code})`)
  }
  if nmach < len(mach_stk) { mach_stk[nmach] = st } else { push(mach_stk, st) }
  nmach += 1
  let endl = lbl("smend")
  var i = 0
  while i < len(st.kids) {
    let state = st.kids[i]
    let v = machine_state_value(st, state)
    let c = emit_bind(`icmp eq i32 {s}, {v}`)
    let body = lbl("sbody");  let nxt = lbl("sarm")
    emit("  br i1 ");  emit(c);  emit(", label %");  emit(body);  emit(", label %");  emit(nxt);  emit("\n")
    emit(body);  emit(":\n");  g_term = false
    emit_block(state.a)
    if not g_term { emit("  br label %");  emit(endl);  emit("\n") }
    emit(nxt);  emit(":\n");  g_term = false
    i += 1
  }
  if not g_term { emit("  br label %");  emit(endl);  emit("\n") }
  emit(endl);  emit(":\n");  g_term = false
  nmach -= 1
}

# `become Name` — a machine state transition when Name is a state of an
# enclosing `machine`, otherwise a scene transition. A scene transition runs the
# source scene's on-exit, stores the target scene id into @L_scene, and runs the
# target's on-enter (two direct calls and a store — no dispatch table).
function emit_become(st: Node) -> void {
  if nmach > 0 {                                        # inside a machine: try a state first
    let m = mach_stk[nmach - 1]
    var target: Node = null
    var i = 0
    while i < len(m.kids) { if (m.kids[i].s == st.s) { target = m.kids[i] };  i += 1 }
    if (target != null) {
      let sv = machine_state_value(m, target)
      let addr = machine_addr(m.a)
      if (addr != null) {
        emit(`  store i32 {sv}, ptr {addr}\n`)
      } else {
        let regv = emit_expr(m.a)
        emit("  call void " + fn_sym("rt_set_reg") + "(i32 ");  emit(regv.code);  emit(", i32 ");  emit(sv);  emit(")\n")
      }
      return
    }
  }
  let sc = find_scene(st.s)                             # else a scene transition
  if (sc == null) { perr(`become: no state or scene {st.s}`) }
  # leave the scene we are in: statically known inside a scene's own handler, else
  # (a global handler, an event listener, a function) whichever scene is live now
  if (g_cur_scene != null) { emit("  call void @scene_exit_");  emit(g_cur_scene.s);  emit("()\n") }
  else { emit("  call void @L_scene_leave()\n") }
  emit("  store i32 ");  emit(itoa(sc.ival));  emit(", ptr @L_scene\n")
  emit("  call void @scene_enter_");  emit(sc.s);  emit("()\n")
}