38 lines
1.2 KiB
Text
38 lines
1.2 KiB
Text
# instance.ludic - a mounted component's record (its props and state), found by where it sits in the
|
|
# tree; one that a build of its screen did not reach is gone, and its state with it
|
|
property UiInst {
|
|
key: string = ""
|
|
cls: UiClass = null
|
|
ptr: pointer = null
|
|
seen: int = 0
|
|
props: Val = null # its props, filled again each frame into the same object
|
|
model: Val = null # and its model, filled in place by the class's model()
|
|
}
|
|
function in_get(ui_st: mut UiState, key: string, k: UiClass) -> UiInst {
|
|
for i in 0 .. len(ui_st.in_list) {
|
|
let it = ui_st.in_list[i]
|
|
if it.key == key and it.cls.name == k.name {
|
|
it.seen = ui_st.in_build
|
|
return it
|
|
}
|
|
}
|
|
let it = new UiInst
|
|
it.key = key
|
|
it.cls = k
|
|
it.ptr = k.make()
|
|
it.seen = ui_st.in_build
|
|
push(ui_st.in_list, it)
|
|
return it
|
|
}
|
|
# after a build of `screen`: its instances the build did not reach are unmounted
|
|
function in_sweep(ui_st: mut UiState, screen: string) -> void {
|
|
var kept = 0
|
|
for i in 0 .. len(ui_st.in_list) {
|
|
let it = ui_st.in_list[i]
|
|
if it.seen == ui_st.in_build or not lc_mine(it.key, screen) {
|
|
ui_st.in_list[kept] = it
|
|
kept += 1
|
|
}
|
|
}
|
|
while len(ui_st.in_list) > kept { List.pop(ui_st.in_list) }
|
|
}
|