53 lines
2.2 KiB
Text
53 lines
2.2 KiB
Text
# verbs.ludic - the only way the clock changes
|
|
export function clock_set_scale(clock_st: mut ClockState, s: float) -> void { clock_st.ck_scale = s }
|
|
export function clock_set_day(clock_st: mut ClockState, d: int) -> void { clock_st.ck_day = d }
|
|
export function clock_set_moon(clock_st: mut ClockState, m: float) -> void { clock_st.ck_moon = m }
|
|
|
|
# the hour, wrapped into [0, 24); setting it never turns the day - that is clock_new_day's
|
|
export function clock_set_hours(clock_st: mut ClockState, h: float) -> void {
|
|
var x = h % 24.0
|
|
if x < 0.0 { x = x + 24.0 }
|
|
clock_st.ck_hours = x
|
|
}
|
|
|
|
function ck_turn(clock_st: mut ClockState, how: int) -> void {
|
|
clock_st.ck_day += 1
|
|
clock_st.ck_moon = (clock_st.ck_moon + 1.0 / clock_st.ck_moon_days) % 1.0
|
|
var d = q_rec(clock_days(clock_st))
|
|
if d == null {
|
|
@alloc_ok("past the ring: more of these in a frame than its records, then kept in it")
|
|
d = new DayTurned
|
|
q_ring_add(clock_days(clock_st), d)
|
|
}
|
|
d.day = clock_st.ck_day
|
|
d.how = how
|
|
q_push(clock_days(clock_st), d)
|
|
}
|
|
|
|
# a new day however it came (a night slept, a collapse); the caller sets the hour first
|
|
export function clock_new_day(clock_st: mut ClockState) -> void { ck_turn(clock_st, DAY_SLEPT) }
|
|
|
|
# run the hours on by `gh` game hours; past midnight the day turns. Only the machine that owns
|
|
# the world moves it - another machine is told the time.
|
|
export function clock_advance(clock_st: mut ClockState, gh: float) -> void {
|
|
if not ck_owns() { return }
|
|
clock_st.ck_hours = clock_st.ck_hours + gh
|
|
while not (clock_st.ck_hours < 24.0) {
|
|
clock_st.ck_hours = clock_st.ck_hours - 24.0
|
|
ck_turn(clock_st, DAY_STAYED_UP)
|
|
}
|
|
}
|
|
|
|
# a new trip: day one at the start hour, the moon somewhere in its month
|
|
export function clock_reset(clock_st: mut ClockState) -> void {
|
|
if clock_st.ck_dice == null {
|
|
clock_st.ck_dice = ck_dice_new(ClockWorld.seed())
|
|
} else { rng_seed(clock_st.ck_dice, ClockWorld.seed()) }
|
|
clock_st.ck_day = 1
|
|
clock_st.ck_hours = clock_st.ck_start_hours
|
|
clock_st.ck_moon = rng_span(clock_st.ck_dice, clock_st.ck_moon_lo, clock_st.ck_moon_hi) % 1.0
|
|
q_clear(clock_days(clock_st))
|
|
}
|
|
|
|
@alloc_ok("once: the clock's dice, seeded again on every new trip after")
|
|
function ck_dice_new(seed: int) -> Rng { return rng_new(seed) }
|